Amiga Format CD 49/Amiga Format CD49 (2000-01-17)(Future Publishing)(GB)(Track 1 of 3)[!][issue 2000-02].iso/-serious-/misc/football/exec/cupupdatematches.rexx

OS/2 REXX Batch file | 1999-11-29 | 12KB | 430 lines

/* ***********************************************************************

   CUP UPDATE MATCHES PROGRAM FOR FOOTBALL REXX SUITE
  ----------------------------------------------------
                   Copyright  Mark Naughton 1997


Version    Date     History
--------------------------------------------------------------------------
 1.0       071297   First release.
           081297   Didn't write the ExtraTime and Penalties lines. While
                    checking through the list from '.scf', the file is
                    opened and each played match is written along with,
                    if applicable, ET and Penalties lines. Added parsing
                    to the matches just played to see if they fail any of
                    the checks.
           131297   Update didn't work. Only changed the first match. Had
                    to rework the method to read the schedule first and
                    then compare it with each line in matches. Now works
                    properly.
           141297   Added error message for Penalties.
           151297   Added error message for Penalties being equal and
                    tidied display.
           280898   Added new error messages. Added pseudo code for
                    addition of checks for Legs and Away Goals.
           290898   Added code to parse 2nd leg matches.
           050998   Amended code for away goals on extra time.
           110998   Fixed major bug which rewrote the schedule file and
                    missed several lines. When it reached the 2nd leg of
                    the 2nd round, it missed the '#1st Leg' line in the
                    recreation of the file. Its fixed and is trimmer than
                    before.
           120998   Amended match checking so if the score is level after
                    extra time with goals scored then away goals count.
           250899   Added error msg to file checks.
 1.1       030999   Converted to use locale. Some error messages, before
                    reading the locale, will still be in English.
                    English language still needs to appear in the datafiles
                    for processing by Football.

**************************************************************************

Procedure
---------

1. Check files exist.
2. Read definition file and see if away goals are involved. Read in
   temporary file from RAM: containing matches with scores entered from
   FOOTBALL.
3. Read in '.scf' file.
4. Loop until all matches have been done; If a match hasn't been played
   then overwrite it with the scores.
5. Open '.scf' file and write the newly amended data to it.
6. Exit.

************************************************************************** */
PARSE ARG league_stuff

version      = 1
input_file   = 'RAM:Football.ctmpfile'
input2_file  = '.scf'
input3_file  = '.cf'
matches.     = '???'
separator    = '*'
ttc          = 0
not_played   = '__   __'
league_file  = "Data/"league_stuff
selines.     = '???'
sdlines.     = '???'
sdc          = 0
awaygoals    = '*CUP_AWAYG='


if open(datafile,"Data/Football.locale",'r') then do
   line = readln(datafile)
   locdir = strip(line)
   close(datafile)
end
else do
   say
   say "ERROR :    (CupUpdateMatches)"
   say
   say "Cannot read 'Data/Football.locale' for the locale settings."
   exit
end

dcupdir = locdir"Football.locale_cup"
locdir = locdir"Exec/CupUpdateMatches.data"

if open(datafile,"ENV:FootballRXPath",'r') then do
   line = readln(datafile)
   rxdir = strip(line)
   close(datafile)
end
else
   rxdir = "SYS:Rexxc/"

if exists(locdir) > 0 then do
  address command rxdir'rx 'locdir
  VarCount = getclip('VarCount')
  do i = 1 to VarCount
    interpret getclip('var.'i)
  end
end
else do
   say
   say "ERROR :    (CupUpdateMatches)"
   say
   say "Cannot find '"locdir"' to read locale settings."
   exit
end

if exists(dcupdir) > 0 then do
  address command rxdir'rx 'dcupdir
  VarCount = getclip('VarCount')
  do i = 1 to VarCount
    interpret getclip('var.'i)
  end
end
else do
   say
   say "ERROR :    (CupScheduler)"
   say
   say "Cannot find '"dcupdir"' to read cup locale settings."
   exit
end

if exists(input_file) = 0 then do
   say
   say cum_error
   say
   say cum_t2"'"input_file"'."
   exit
end

if exists(league_file||input2_file) = 0 then do
   say
   say cum_error
   say
   say cum_t2"'"league_file||input2_file"'."
   exit
end

if exists(league_file||input3_file) = 0 then do
   say
   say cum_error
   say
   say cum_t2"'"league_file||input3_file"'."
   exit
end

if open(datafile,league_file || input3_file,'r') then do
   do while ~eof(datafile)
      line = readln(datafile)
      if pos(awaygoals,line) > 0 then awayg = delstr(line,1,11)
   end
   close(datafile)
end
else do
   say
   say cum_error
   say
   say cum_t3"'"league_file || input3_file"'."
   exit
end

ttc = 0
if open(datafile,input_file,'r') then do
   do while ~eof(datafile)
      line = readln(datafile)
      if line ~= '' then do
         ttc = ttc + 1
         matches.ttc = line
      end
   end
   close(datafile)
end
else do
   say
   say cum_error
   say
   say cum_t3"'"input_file"'"cum_t4
   exit
end

/* parsing matches array for errors */

errors  = ' '
errct   = 0
legs    = 0

do i=1 to ttc
   mkr = 0
   if pos("#Round=",matches.i) > 0 then do
      if pos("1st Leg",matches.i) > 0 then
         legs = 1
      if pos("2nd Leg",matches.i) > 0 then
         legs = 2
   end
   if pos('#',matches.i) = 0 then do
      sh  = substr(matches.i,32,2)
      sa  = substr(matches.i,37,2)

      if sa  = sh then mkr = 1
      if sa ~= sh & legs~=2 then iterate
      if sa ~=sh & legs=2 then mkr = 1
      if pos(not_played,matches.i) > 0 then mkr = 3   /* was 0 - unsure why... */

   /* this is where the check for away goals and if its equal after two legs */
   /* if so then extra time then penalties needs to be played. */
   /* sa and sh need to be added together with the 1st leg before checking */
   /* if no winner, (if away goals set), check away goals else proceed onto */
   /* extra time and penalties */

      if mkr = 1 & legs = 1 then iterate
      if mkr = 1 & legs = 2 then do
         j = i + 1
         if pos("#1st Leg",matches.j) > 0 then do
            i = j
            fh  = substr(matches.i,32,2)
            fa  = substr(matches.i,37,2)
            shs = fh + sh
            sas = fa + sa

            if shs = sas then do
               if pos("YES",awayg) > 0 then do
                  if fh = sa then mkr = 1
                  if fh ~= sa then iterate
               end
               else
                  mkr = 1
            end
            if shs ~= sas then iterate
            if pos(not_played,matches.i) > 0 then mkr = 3
         end
         else do
            errct = errct + 1
            errors = errors" "i" "
            iterate
         end
      end

      if mkr = 1 then do
         j = i + 1
         if pos("#Score After Extra Time",matches.j) > 0 then do
            i = i + 1
            eh  = substr(matches.i,32,2)
            ea  = substr(matches.i,37,2)
            if eh = "" | ea = "" then mkr = 3
            if pos(not_played,matches.i) > 0 then mkr = 3

            if mkr ~= 3 then do
               if legs = 2 then do
                  shs = fh + eh
                  sas = fa + ea
                  if shs ~= sas then iterate
                  if pos("YES",awayg) > 0 then do
                     if eh = sa then do
                        if eh = eh & sa = ea then
                           mkr = 1
                        else
                           iterate
                     end
                     if eh ~= sa then iterate
                  end
                  else
                     mkr = 1
               end
               else do
                  if eh =  ea then mkr = 1
                  if eh ~= ea then iterate
               end
            end
            if eh < sh | ea < sa then mkr = 3
         end
      end
      if mkr = 3 then do
         errct = errct + 1
         errors = errors" "i" "
         iterate
      end
      if mkr = 1 then do
         j = i + 1
         if pos("#Penalties",matches.j) > 0 then do
            i = i + 1
            ph  = substr(matches.i,32,2)
            pa  = substr(matches.i,37,2)
            if ph = "" | pa = "" then mkr = 3

            if ph =  pa then mkr = 3
            if ph ~= pa then iterate
            if pos(not_played,matches.i) > 0 then mkr = 3
         end
      end
      if mkr = 3 then do
         errct = errct + 1
         errors = errors" "i" "
         iterate
      end
   end
end

if errct > 0 then do
   say
   say center(cum_t6"'"league_stuff"'",78)
   say "-------------------------------------------------------------------------------"
   say
   do j=1 to ttc
      if pos("#Round",matches.j) = 0 then do
         if pos(" "j" ",errors) > 0 then
            say ">"left(matches.j,70)""cum_t7
         else
            say ">"left(matches.j,70)"<"
      end
   end
   say
   say
   say errct" "cum_t8
   say
   say cum_t9
   say cum_t10
   say
   say "1. "cum_t11
   say "   "cum_t12
   say "2. "cum_t13
   say "   "cum_t14
   say "3. "cum_t15
   say "   "cum_t16
   say "4. "cum_t17
   say "   "cum_t18
   say "5. "cum_t19
   say "   "cum_t20
   say "6. "cum-t21
   say "   "cum_t22
   say "7. "cum_t23
   say "   "cum_t24
   say "8. "cum_t25
   say "   "cum_t26
   say "9. "cum_t27
   say
   say cum_t28
   say cum_t29
   say
   say "-------------------------------------------------------------------------------"
   exit
end

secount = 0
if open(datafile,league_file||input2_file,'r') then do
   do while ~eof(datafile)
      line = readln(datafile)
      secount         = secount + 1
      selines.secount = line
   end
   close(datafile)
end
else do
   say
   say cum_error
   say
   say cum_t3"'"league_file||input2_file"'"cum_t4
   exit
end

address command 'delete >NIL: 'input_file

et. = '???'
pn. = '???'
do j=1 to secount
   mkr = 0
   if pos(separator,selines.j) = 0 then do
      shome = strip(substr(selines.j,1,30))
      saway = strip(substr(selines.j,41,30))
      do i=1 to ttc
         home  = strip(substr(matches.i,1,30))
         away  = strip(substr(matches.i,41,30))
         mkr = 0

         if shome = home & saway = away then do
            if pos(not_played,selines.j) > 0 then do
               selines.j = matches.i
               mkr = 1
            end
            g = i + 1
            if pos("#1st Leg",matches.g) > 0 then do
               a = j + 1
               dif = 1
            end
            else do
               a = j
               dif = 0
            end
            if mkr = 1 then do
               k = i + 1 + dif
               if pos("#Score After Extra Time",matches.k) > 0 & pos(not_played,matches.k) = 0 then
                  et.a = matches.k
               k = k + 1
               if pos("#Penalties",matches.k) > 0 & pos(not_played,matches.k) = 0 then
                  pn.a = matches.k
            end
         end
         if mkr = 1 then leave
      end
   end
end

if selines.secount ~='' & selines.secount ~='*' then do
   secount = secount + 1
   sdlines.secount = "*"
end
if open(datafile,league_file||input2_file,'w') then do
   do j=1 to secount
      if selines.j~='' then do
         writeln(datafile,selines.j)
         if pos("???",et.j) = 0 & et.j ~= "" then
            writeln(datafile,et.j)
         if pos("???",pn.j) = 0 & pn.j ~= "" then
            writeln(datafile,pn.j)
      end
   end
   close(datafile)
end
else do
   say
   say cum_error
   say
   say cum_t3"'"league_file || input2_file"'"cum_t5
end

exit